;*************************************************************************
;
;  Quick binary file loader
;  	Type this program into memory at zero using "EN 0". All bytes
;	will fit on one line. Run at zero (EX 0), then send the file
;	PC2FLOP.COM (8-bit binary) into the Sol-20 serial port. Finally, 
;	reset the computer and run PC2FLOP from 0100 (EX 100).
;
;************************************************************************

sioCtl	equ	0F8h		;serial port control register
sioDat	equ	0F9h		;serial port data register
sioRdrf	equ	040h		;mask to test for receive data

	org	0
	
	lxi	h,0100h		;load at 0100h
	in	sioDat		;clear out possible garbage

loop	in	sioCtl		;wait for a character
	ani	sioRdrf	
	jz	loop

	in	sioDat		;get the character
	mov	m,a		;store it
	inx	h		;move to next location
	jmp	loop

	end
