/024 SUBROUTINE TRANSLATES TELEX TO ACII
/
/CALL	:JMS TLXAS WITH TELEX CHARACTER IN AC
/	RETURN CHARACTER IS SHIFT
/	RETURN WITH ASCII CHARACTER IN AC
/
/WHO IS TRANSLATED AS $  
/? IS TRANSLATAD AS *

BELL IS TRANSLATED AS ;
/
TLXAS,	 0
	AND C37		/MASK 5 BITS
	DCA TLXTMP	/TEMP. STORAGE
	TAD TLXTMP
	SNA
	JMP TLXOUT	/BLANK
	TAD M2
	SNA
	JMP TLXCR	/CARRIAGE RETRN
	TAD M6
	SNA
	JMP TLXNL	/NEW LINE
	TAD M23
	SNA
	JMP TLXSW1	/FIGURESHIFT
	TAD M4
	SNA CLA
	JMP TLXSW0	/LETTERSHIFT
	TAD TLXTMP	/GET CHARACTER AGAIN
	TAD TLXLA	/ADD LISTADDRESS
	DCA TLXTMP	/TEMP STORAGE
	TAD TLXSW	/WHICH SIDE?
	SZA CLA
	MP TLXRGT	/RIGHT SIDE
	TAD I TLXTMP	/GET ASCII 6 BIT
	RTR
	RTR
	RTR
TLXMS,	AND C77		/MASK 6 BIT
	TAD M40
	SPA
	TAD C100	/CHAR<40:300<=CHAR<=337
	TAD C240	/CHAR>44:240<=CHAR<=277
TLXOUT,	ISZ TLXAS	/NORMAL RETURN
	JMP I TLXAS
/
TLXRGT,	TAD I TLXTMP
	JMP TLXMS
/
TLXSW1,	IAC
TLXSW0,	DCA TLXSW	/REMEMBER WICH SHIFT
	JMP I TLXAS	/RETURN SHIFT
/
TLXCR,	TAD C215
	JMP TLXOUT
TLXNL,	 TAD C212
	JMP TLXOUT
/
TLXLA,	 TLXLST
TLXLST,	0
	2465	/T	5
C37,	37
	1771	/O	9
	4040	/SPACE
	1036	/H	^
	1654	/N	,
	1556	/M	.
M40,	-40
	1451	/L	)
	2264	/R	4
	0735	/G	]
	1170	/I	8
	2060	/P	0
	0372	/C	:
	2675	/V	=
	0563	/E	3
	3253	/Z	+
	0477	/D	WHO=$
	0252	/B	?=
	2347	/S	'
	3166	/Y	6
	0633	/F	[
	3057	/X	/
	0155	/A	-
	2762	/W	2
	1273	/J	BELL=;
C100,	100
	2567	/U	7
	2161	/Q	1
	1350	/K	(
/
/VARIABLES
/
TLXTMP,	0
TLXSW,	0
/
/GENERAL CONSTANTS
M2,	-2
M4,	-4
M6,	-6
M23,	-23
C77,	77
C212,	212
C215,	215
C240,	240