;*****************************************************************************
;
;  Flop2PC - Transfer floppy image to PC over a serial port
;
;	This program transmits an image of an Altair high density (HD)
;	floppy to a PC through either port on an 88-2SIO or through an
;	88-SIO at 0/1 using the XMODEM protocol. The disk contains
;	a single 9984 byte sector per track plus track and checksum
;	meta-data. The meta-data is not transferred.
;
;	This program runs standalone at 0x100 or under CP/M. Console
;	I/O is done directly through the first port on an 88-2SIO.
;
;	Written by Mike Douglas
;
;	Rev	 Date	    Desc
;	1.0	 06/22/20   Original
;
;       1.1	 06/25/20   Prompt for number of tracks (77 or 80)
;
;	1.2	 07/06/20   Use common 3 digit binary to decimal conversion
;			    routine for track number display. Use only tracks
;			    0-71 on the top and 0-76 on the bottom for better
;			    reliability with old media and for compatibility
;			    with 8" drives (77 tracks). See BIOS.ASM for more
;			    information. Use 10,240 bytes per track instead
;			    of 9,984.
;
;	1.3	 07/14/20   Wait 200us instead of 100us for head change.
;			    Extra margin for old drives.
;
;*****************************************************************************

; Disk information equates

NUMTRKS	equ	149		;number of tracks
ENDTOP	equ	72*2		;no top tracks from cylinder 72 and up
NUMSEC	equ	1		;number of sectors per track
SECLEN	equ	10240		;sector length (as transmitted)
TRKLEN	equ	(NUMSEC*SECLEN)	;length of track in bytes
MINDRV	equ	0		;first drive number
MAXDRV	equ	3		;max drive number 
CPUSPED	equ	2000		;CPU speed in khz for delay subroutine

RDTRIES	equ	6		;read tries
; Monitor, CP/M boot entry points

MONITOR	set	init		;no monitor, just start over
CPMBOOT	set	0		;CP/M warm boot jump vector

; XMODEM equates

PKTLEN	equ	128		;128 byte xmodem packet length
SOH	equ	001h
EOT	equ	004h
ACK	equ	006h
NAK	equ	015h
EOF	equ	01ah		;ctrl-z character
XMTRIES	equ	10		;number of xmodem retries

; CP/M Equates

WBOOT	equ	0		;warm boot jump vector
BDOS	equ	5		;BDOS jump vector

; Misc equates

CR	equ	13		;ascii for carriage return
LF	equ	10		;ascii for line feed
DEL	equ	7fh		;ascii DEL
BS	equ	08h		;ascii backspace
CTRLC	equ	03		;ascii for control-c
JMPINST	equ	0c3h		;jump instruction opcode

	org	0100h		;load address
;-----------------------------------------------------------------------------
;   Initialize for transfer
;-----------------------------------------------------------------------------
init	lxi	sp,ourStk	;initialize stack pointer
	call	chkCpm		;set flag for CP/M or not
	call	sizeRam		;determine amount of RAM available
	call	s2Init		;initialize the 88-2SIO ports
	mvi	a,MINDRV	;a=default drive
	sta	drvNum		;need for pgmExit
	mvi	a,0ffh		;init disk driver selected disk
	sta	curDrv		;  to "none"

;  Display welcome message, then get the drive number and port number
;    to use for the transfer from the operator.

	lxi	h,mWelcom	;display welcome message
	call	dispMsg

; getDrv - get drive number or letter from the user.

getDrv	call	dDeslct		;deselect possibly selected drive
	lxi	h,mDrive	;display drive number prompt
	call	dispMsg
	call	rcvCon		;get byte from the console
	ori	20h		;upper case letters to lower case
	cpi	'x'		;exit requested?
	jz	pgmExit		;yes
	lxi	h,baseDrv	;ascii 1st drive - baseDrv = 0
	sub	m
	jm	getDrv		;error, entry was < first drive
	cpi	MAXDRV-MINDRV+1	;validate <= max drive
	jnc	getDrv		;invalid, prompt again
	adi	MINDRV		;restore offset of 1st drive (if any)
	sta	drvNum		;save the drive number to use
	call	dRestor		;restore to track 0 (selects drive)

; getPort - get pseudo port number 0-2 from the user.

getPort	lxi	h,mPort		;display transfer port prompt
	call	dispMsg
	call	rcvCon		;get byte from the console
	ori	20h		;upper to lower case, nums not affected
	cpi	'x'		;exit requested?
	jz	pgmExit		;yes
	sui	'1'		;un-ascii
	cpi	3		;validate ascii 1-3
	jnc	getPort		;invalid, prompt again
	sta	xfrPort		;save the pseudo port to use

; Prompt the user to start the XMODEM receive operation on the PC. 
;    Wait for a clear receive line for a least one second, then start
;    looking for NAK or 'C' (crc protocol) from the PC

	lxi	h,mStart	;display start file transfer prompt
	call	dispMsg

clrRcv1	call	rcvByte		;loop until input clear for 1 second
	jnz	clrRcv1

	xra	a		;set CRC flag to false (checksum mode)
	sta	crcFlag
waitNak	call	chkQuit		;give user chance to abort
	call	rcvByte		;wait for a character
	cpi	NAK
	jz	haveNak		;have a NAK, use checksum protocol
	cpi	'C'		;CRC protocol requested?
	jnz	waitNak		;no
	sta	crcFlag		;set crc flag non-zero = CRC mode

;  NAK or 'C' received meaning the XMODEM receive has started. Initialize
;     for the transfer.

haveNak	mvi	a,0ffh		;track position on drive not known
	sta	curTrk
	xra	a		;init track we want to zero
	sta	trkNum
	inr	a		;init xmodem block number to one
	sta	blkNum
	lxi	h,trkBuf	;trkBuf is initial starting point for
	shld	sndPtr		;   XMODEM send

;-----------------------------------------------------------------------------
;  mainLp - Loop through all tracks on the disk buffering as many tracks
;    as will fit in RAM before sending via xmodem, then repeat.
;-----------------------------------------------------------------------------
mainLp	lxi	h,trkBuf	;disk buffering always start at trkBuf
	shld	trkPtr

; Read and buffer bufTrks tracks unless all tracks on drive reached first

	call	dLoad		;load drive head
bufLoop	call	readTrk		;read into trkBuf
	lda	trkNum		;increment track number (preserve HL)
	inr	a
	sta	trkNum	
	cpi	NUMTRKS		;done all tracks?
	jz	sendBuf		;yes, go send the buffered tracks

	xchg			;de=current track pointer
	lhld	bufEnd		;hl=end of buffering space
	call	cmpDeHl		;compare current-end
	jc	bufLoop		;still room, keep going	

; Track buffer is full or all tracks have been read. Send the buffered
;    tracks via xmodem.

sendBuf	call	dUnload		;unload the head
	call	sndTrks		;send the buffered tracks via xmodem

	lda	trkNum		;A=current track number
	cpi	NUMTRKS		;done all tracks?
	jnz	mainLp		;no, not done yet

; The entire disk has been read and (mostly) transmitted. See if there are
;    left over bytes to send. If so, send them.

	mov	a,l		;hl->next packet to send, a=lsb of ptr
	cpi	trkBuf AND 0ffh	;pointing to lsb of address of trkBuf?
	jz	noExtra		;same, no extra bytes to send
	call	sndPkt		;otherwise, send one last packet

; Send EOT and wait for response. Then display the success message and
;    start the program over.

noExtra	call	sndEot		;send and get response for EOT

	mvi	l,0		;seek to track 0 (don't use dRestor)
	call	dSeek

	lxi	h,mDone		;print the all done message
	call	dispMsg
	jmp	getDrv		;start over asking for a drive
	
;-----------------------------------------------------------------------------
; readTrk - read NUMSEC sectors from the current track into a trkBuf as
;   pointed to by trkPtr. After the track is read, trkPtr is updated
;   by the length of a track to point to the next track buffer. This
;   saved value is also returned in HL.
;-----------------------------------------------------------------------------
readTrk	mvi	e,1		;E=re-seek counter

rtSeek	push	d		;save re-seek counter
	lxi	h,trkNum	;get desired track from trkNum	
	mov	l,m		;and put into l
	call	dSeek		;seek to the track
	pop	d		;restore re-seek counter

	mvi	d,RDTRIES	;D=count of read tries
	
rtLoop	call	dNxtSec		;wait for index pulse, HL->trkBuf
	call	dRead		;read the track
	jz	rtExit		;successful read, exit

	dcr	d		;decrement read retry count
	jnz	rtLoop		;not zero, try again

	dcr	e		;decrement seek retry counter
	jnz	rtError		;re-seeks done, give up

	call	dRestor		;else restore to track zero
	jmp	rtSeek		;re-seek and try again
	call	dspErr		;give up, display the error

rtError	call	dspErr		;display the error
				;fall into rtExit to continue

rtExit	lhld	trkPtr		;increment track pointer by track length
	lxi	d,TRKLEN	;de=bytes in a track
	dad	d		;hl=start of next track in trkBuf
	shld	trkPtr
	ret

;-----------------------------------------------------------------------------
; sndTrks - send the tracks buffered in trkBuf via xmodem. trkPtr points
;    to the end+1 of the data to send
;-----------------------------------------------------------------------------
sndTrks	lhld	trkPtr		;hl=end of buffered data + 1
	xchg			;de=end of buffered data + 1
	lhld	sndPtr		;hl=start tranmission address
sndLoop	push	d		;save end pointer
	call	sndPkt		;send a packet
	pop	d		;de=end pointer

; At this point, hl->start of next packet and de->last byte read from disk+1.
;    If the next XMODEM packet will go past the end of the disk data,
;    we don't want to send it yet.

	lxi	b,PKTLEN	;bc=length of XMODEM packet
	dad	b		;hl=address at end of NEXT packet + 1
	call	cmpDeHl		;compare disk end - end of next packet
	jc	sndDone		;next packet will pass the end, stop
	lxi	b,-PKTLEN	;restore hl
	dad	b
	jmp	sndLoop

; sndDone - all the packets we can send have been sent. Move any bytes
;    left over to just before the start of trkBuf. The next group of
;    xmodem packets will be transmitted starting there.

sndDone	call	subDeHl		;hl=de-hl = left over byte count - PKTLEN
	mov	a,l		;a=left over count - PKTLEN
	adi	PKTLEN		;a=left over byte count
	mov	b,a		;b=count of bytes to move
	lxi	h,trkBuf	;hl->start of trkBuf
	jz	mvDone		;no bytes to move, we're done
	
; Copy the leftover data backwards to just before the track buffer. The
;   next XMODEM send sequence will start at the beginning of this copied
;   data instead of at the start of trkBuf.

moveLp	dcx	h		;hl->memory just before trkBuf
	dcx	d		;de->unsent bytes from end of trkBuf
	ldax	d		;move from end of trkBuf to before trkBuf
	mov	m,a	
	dcr	b
	jnz	moveLp
mvDone	shld	sndPtr		;save address from which to send next time
	ret

;-----------------------------------------------------------------------------
; sndPkt - send an xmodem format 128 byte packet. HL points to the 128 byte
;    buffer to send. On exit, HL points to the next 128 byte boundary.
;-----------------------------------------------------------------------------
sndPkt	mvi	a,XMTRIES	;init retry counter
	sta	xmRetry

; First, send header bytes

reSend	call	chkQuit		;check for ctrl-c
	push	h		;save hl for possible re-send
	mvi	a,SOH		;1st byte is SOH
	call	sndByte
	lda	blkNum		;2nd byte is the block number
	call	sndByte
	cma			;2nd complement of block number
	call	sndByte

; Init checksum and CRC and packet length for transmission of data portion

	xra	a		;init crc
	sta	crc16
	sta	crc16+1
	lxi	d,PKTLEN*256	;d=byte counter, e=0 (checksum)

; Loop sending the data bytes and updating checksum and CRC

pktLoop	mov	a,m
	call	sndByte		;send and update checksum in e
	call	calCrc		;update the CRC
	inx	h		;point to next byte
	dcr	d		;decrement bytes remaining
	jnz	pktLoop

; Send checksum or CRC based on crcFlag

	lda	crcFlag		;crc or checksum?
	ora	a
	jz	sndCsum		;flag clear = checksum
	lda	crc16+1		;a=high byte of CRC
	call	sndByte		;send it
	lda	crc16		;a=low byte of crc
	jmp	sndSkip		;skip next instruction	
sndCsum	mov	a,e		;send the checksum byte
sndSkip	call	sndByte

;  All bytes sent. Wait for the response.

	call	rcvByte		;get the response character
	jz	sndFail		;timeout on response
	cpi	ACK		;ack received?
	jnz	sndFail		;no, send failed
	lda	blkNum		;increment block number
	inr	a
	sta	blkNum
	pop	b		;remove pushed hl, but don't clobber hl
	ret

; sndFail - ACK not received, decrement retry and try again.

sndFail	lxi	h,xmRetry	;point to retry counter
	dcr	m
	jz	xmFail		;retries used up, failed xmodem transfer

; If we've had 3 NAKs on the 1st packet and CRC is selected, assume
;   we took so long to send the 1st packet due to disk retries that
;   the receiver has since timed out and switched to checksum

	lda	crcFlag		;are we in CRC mode
	jz	clrRcv2		;no, ignore the rest of this
	lda	blkNum		;on block 1?
	dcr	a
	jnz	clrRcv2		;no, go on
	lda	xmRetry		;failed three times in a row on block 1?
	sui	XMTRIES-3
	jnz	clrRcv2		;no
	sta	crcFlag		;clear crcFlag to force checksum

;  clrRcv2 - wait for one second of line clear time and send packet again.

clrRcv2	call	rcvByte		;wait for 1 second of clear line
	jnz	clrRcv2
	pop	h		;restore pointer to the packet
	jmp	reSend		;re-send the packet

;  xmFail - Display failure message then restart program

xmFail	lxi	h,mXmdm		;xmodem failure message
	call	dispMsg
	lxi	sp,ourStk	;initialize stack pointer
	jmp	getDrv		;start over asking for drive

;-----------------------------------------------------------------------------
; calCrc - update the 16-bit CRC with one more byte. 
;    (Copied from M. Eberhard)
; On Entry:
;   a has the new byte
;   crc16 is current except this byte
; On Exit:
;   crc16 has been updated
;   Trashes a,bc
;-----------------------------------------------------------------------------
calCrc	push	d
	push	h
	lhld	crc16		;get CRC so far
	xra	h		;XOR into CRC top byte
	mov	h,a
	lxi	b,1021h		;bc=CRC16 polynomial
	mvi	d,8		;prepare to rotate 8 bits

; do 8 bit shift/divide by CRC polynomial

cRotLp	dad	h		;16-bit shift
	jnc	cClr		;skip if bit 15 was 0
	mov	a,h		;CRC=CRC xor 1021H
	xra	b
	mov	h,a
	mov	a,l
	xra	c
	mov	l,a
cClr	dcr	d
	jnz	cRotLp		;rotate 8 times

; save the updated CRC and exit

	shld	crc16		;save updated CRC
	pop	h
	pop	d
	ret

;-----------------------------------------------------------------------------
;  sndEot - send EOT character and wait for ACK response
;-----------------------------------------------------------------------------
sndEot	mvi	a,XMTRIES	;init retry counter
	sta	xmRetry
reEot	mvi	a,EOT		;send the EOT
	call	sndByte
	call	rcvByte		;wait for response
	jz	eotFail		;timeout
	cpi	ACK		;ack received?
	jnz	eotFail		;no, eot send failed
	ret			;otherwise, we're done.

; timeout waiting for ACK to EOT. Decrement retry counter and try again

eotFail	lxi	h,xmRetry	;point to retry counter
	dcr	m
	rz			;just give up - xfer was probably good
clrRcv3	call	rcvByte		;wait for 1 second of clear line
	jnz	clrRcv3
	jmp	reEot		;try again

;-----------------------------------------------------------------------------
; dispMsg - display the null-terminated message passed in hl on the
;    console device. Clobbers b, hl
;-----------------------------------------------------------------------------
dispMsg	mov	a,m		;get the next message byte
	ora	a		;null terminates
	rz
	mov	b,a		;conOut wants character in b
	call	conOut
	inx	h		;move to next byte
	jmp	dispMsg

;-----------------------------------------------------------------------------
; rcvCon - Receive a character from the console device, echo it, then
;   wait for a CR. Exits program if Ctrl-c typed. Returns with invalid
;   character (null) if BS or DEL pressed after 1st character
;   Returns character in a, clobbers b.
;-----------------------------------------------------------------------------
rcvCon	call	conIn		;check for input
	jz	rcvCon		;nothing
	ani	7fh
	cpi	CTRLC		;abort requested?
	jz	pgmExit		;yes
	cpi	CR		;return pressed?
	rz			;yes, don't echo it
	mov	b,a		;conOut needs character in b
	call	conOut		;echo it

; Wait for CR, then return 1st character typed

rcvCr	call	conIn		;check for input
	jz	rcvCr		;nothing
	ani	7fh
	cpi	CTRLC		;abort requested?
	jz	pgmExit		;yes
	cpi	DEL		;delete
	rz			;yes, return DEL character
	cpi	BS		;backspace?
	rz			;yes, return BS character
	cpi	CR		;return pressed?
	jnz	rcvCr		;no, keep waiting
	mov	a,b		;return 1st character typed
	ret

;-----------------------------------------------------------------------------
; sndByte - send the byte in a through the specified transfer port. 
;     Adds the byte to register e for checksum. Clobbers b.
;     XMODEM send routine assumes serOut returns with a containing
;     the character sent.
;-----------------------------------------------------------------------------
sndByte	mov	b,a		;b=byte to transmit
	add	e		;update checksum
	mov	e,a		;e=updated checksum
	lda	xfrPort		;a=port to use for transfer
	jmp	serOut		;send the character

;-----------------------------------------------------------------------------
; rcvByte - Receive a byte from specified transfer port with a one second
;     timeout. If a timeout occurs, zero is returned in A and the zero 
;     flag is true. Otherwise, the character is returned in A (could be
;     zero) and zero flag is false. ONESEC must be set based on processor
;     speed and the number of cycles in the serIn call + 59. 
;     Clobbers a, b and c.
;-----------------------------------------------------------------------------
rcvByte	lxi	b,ONESEC	;bc=cycles through this loop for 1s
rcvWait	lda	xfrPort		;(13) a=port to use for transfer
	call	serIn		;(17+cycles in serIn)look for a byte
	rnz			;(5)byte received
	dcx	b		;(5)otherwise, decrement timer
	mov	a,b		;(5)one second expire?
	ora	c		;(4)
	jnz	rcvWait		;(10)no, keep waiting
	ret			;return with timeout (zero true and in a)

;-----------------------------------------------------------------------------
; dspErr - display the track number which just had a read error. 
;-----------------------------------------------------------------------------
dspErr	lxi	h,errTrk	;hl->where to put ascii decimal
	lda	trkNum		;a=track with error on it
	call	bin2dec		;track to ascii
	lxi	h,mTrkErr	;hl->track error message
	jmp	dispMsg		;display the error and return

;--------------------------------------------------------------
; bin2dec - Binary byte in A to 3 ASCII digits at (HL) with
;   leading zero suppression.
;--------------------------------------------------------------
bin2dec	mvi	m,'0'		;start with ASCII zero
	
lp100	sui	100		;count 100s
	jc	do10s		;no more 100s
	inr	m		;count the 100
	jmp	lp100

do10s	adi	100		;put back the extra 100
	inx	h		;move to 10s digit
	mvi	m,'0'		;start with ASCII zero

lp10	sui	10		;count 10s
	jc	do1s		;no more 10s
	inr	m		;count the 10
	jmp	lp10

do1s	adi	10+'0'		;compute ASCII 1s digit
	inx	h		;move to 1s digit
	mov	m,a		;store it

; suppress leading zeros

	dcx	h		;back to 100s to zero suppress
	dcx	h
	mov	a,m		;A=ASCII 100s digit
	cpi	'0'		;leading zero?
	rnz			;no
	mvi	m,' '		;else, suppress the zero

	inx	h		;leading zero in 10s digit?
	mov	a,m
	cpi	'0'		;leading zero?
	rnz			;no
	mvi	m,' '		;else, suppress the zero
	ret

;--------------------------------------------------------------
; chkQuit - check for the user to request abort (ctrl-c). If
;    a character is present on the console port, read it and
;    see if ctrl-c. Clobbers A
;--------------------------------------------------------------
chkQuit	call	conIn		;check for console input
	rz
	ani	7fh
	cpi	CTRLC		;abort requested?
	rnz			;no

; Ctrl-C typed while program is running. Return to drive prompt.

	lxi	sp,ourStk	;initialize stack pointer
	jmp	getDrv		;start over asking for drive num

;--------------------------------------------------------------
; pgmExit - Exit to CP/M or to the monitor ROM based on the
;    CP/M flag
;--------------------------------------------------------------
pgmExit	lda	cpmFlag		;running under CP/M?
	ora	a
	jnz	cpmExit		;yes

; Exit to ROM monitor

	lxi	h,mExit		;display "exiting" message
	call	dispMsg
	jmp	MONITOR		;jump to ROM monitor entry point

; CP/M exit. If boot drive was used, prompt user to insert CP/M disk

cpmExit	lda	drvNum		;boot drive used?
	sui	MINDRV
	jnz	noDisk		;not 1, disk prompt not needed
	lxi	h,mCpm		;display "insert cp/m disk"	
	call	dispMsg
	call	rcvCon		;wait for a character
noDisk	lxi	h,mExit		;display "exiting" message
	call	dispMsg
	jmp	CPMBOOT		;reboot CP/M

;--------------------------------------------------------------
; chkCpm - check if running under CP/M. CP/M flag is set true
;   (non-zero) if yes, cleared otherwise.
;--------------------------------------------------------------
; First, initialize entries for stand-alone

chkCpm	xra	a
	sta	cpmFlag		;clear CP/M flag
	mvi	a,MINDRV+'0'	;ascii for minimum drive number
	sta	mDrvMin		;store in the drive prompt message
	sta	baseDrv		;ascii 1st drive - baseDrv = 0
	mvi	a,MAXDRV+'0'	;ascii for max drive number
	sta	mDrvMax

; Determine if we're under CP/M or standalone. CP/M is assumed if
;   a jump instruction is present at the CP/M warm start location (0)
;   and five more jumps (e.g., a jump table) is present at the
;   jump-to destination.
		
	lda	WBOOT		;see if jump instruction present for CP/M
	cpi	JMPINST
	rnz			;no, not CP/M

; A jump instruction is present at the CP/M warm boot location (0),
;   now see if that jump points to five more jumps. If so, assume CP/M

	lxi	h,WBOOT+1	;point to lsb of jump address
	mov	e,m		;e=low byte of jump
	inx	h
	mov	d,m		;de=destination of jump
	mvi	b,5		;look for 5 more jumps (a jump table)
jmpTest	ldax	d		;a=opcode at jump destination
	sui	JMPINST		;another jump present?
	rnz			;no, not CP/M
	inx	d		;move to next jump
	inx	d
	inx	d
	dcr	b
	jnz	jmpTest
	dcr	a		;a=0ffh
	sta	cpmFlag		;CP/M flag to non-zero = true

; We're running under CP/M. Change drive prompt message to show drive
;    letters instead of drive numbers and change baseDrv to convert
;    an 'A' to the base drive number (MINDRV).

	mvi	a,'A'		;'A' in drive message instead of number
	sta	mDrvMin
	adi	MAXDRV-MINDRV	;max drive letter
	sta	mDrvMax
	mvi	a,'a'		;ascii 1st drive - baseDrv = 0
	sta	baseDrv
	ret

;------------------------------------------------------------------
; sizeRam - determine how much RAM we have for buffering tracks.
;   Sets the bufEnd variable which points to end address of 
;   the last possible track buffer + 1
;------------------------------------------------------------------
; If running under CP/M, use the BIOS pointer to determine the top
;    of available RAM. Otherwise, size RAM manually.

sizeRam	lhld	BDOS+1		;hl=BDOS entry address
	mvi	l,0		;hl->top of usable RAM+1

	lda	cpmFlag		;running under CP/M?
	ora	a
	jnz	ramEnd		;yes, we have the end of RAM

;  Not under CP/M. Find the end of RAM manually.

	lxi	h,(trkBuf+0ffh) AND 0ff00h   ;next 256 byte boundary
ramLoop	mov	a,m		;a=current RAM content
	inr	m		;change RAM
	cmp	m		;did RAM change?
	mov	m,a		;restore RAM
	jz	ramEnd		;end of RAM found
	inr	h		;next page
	jnz	ramLoop

	dcr	h		;force end to FF00 instead of 0000

; ramEnd - end of RAM found. Now determine the end address + 1 of the
;   last track buffer that will fit in RAM. Store in bufEnd

ramEnd	xchg			;de=end of RAM + 1
	mvi	a,-((TRKLEN SHR 8) + 1) AND 0ffh
	cmp	d		;force de < (10000h - TRKLEN)
	jnc	topOk
	mov	d,a		;limit max address
topOk	lxi	h,trkBuf	;hl=start of track buffer
	lxi	b,TRKLEN	;bc=length of track in bytes

; Loop increasing hl by TRKLEN until hl > end of RAM.

bfEndLp	dad	b		;hl=hl+track length
	call	cmpHlDe		;compare hl-de
	jc	bfEndLp		;still more room, keep going

; Subtract one track length from hl, this will be the end address + 1 of
;   the the last track buffer that will fit in RAM

	lxi	b,-TRKLEN	;subtract one track length
	dad	b		;hl = end address of last track + 1
	shld	bufEnd		;save as bufEnd
	ret

;--------------------------------------------------------------------
; cmHlDe - compare HL-DE. Carry set if HL<DE, carry clear if HL>=DE
;--------------------------------------------------------------------
cmpHlDe	mov	a,l		;compare HL-DE, do lsbs first
	sub	e
	mov	a,h		;do msbs
	sbb	d
	ret			;carry set HL<DE, clear HL>=DE

;--------------------------------------------------------------------
; cmDeHl - compare DE-HL. Carry set if DE<HL, carry clear if DE>=HL
;--------------------------------------------------------------------
cmpDeHl	mov	a,e		;compare DE-HL, do lsbs first
	sub	l
	mov	a,d		;do msbs
	sbb	h
	ret			;carry set DE<HL, clear DE>=HL

;--------------------------------------------------------------------
; subDeHl - HL=DE-HL
;--------------------------------------------------------------------
subDeHl	mov	a,e		;subtract DE-HL, do lsbs first
	sub	l
	mov	l,a		;lsb result in l
	mov	a,d		;do msbs
	sbb	h
	mov	h,a		;msb result in h	
	ret

;---------------------------------------------------------------------
; Message constants
;---------------------------------------------------------------------
mWelcom	db	cr,lf,lf
	db	'===== Floppy to PC Image Transfer, Version 1.3 ====='
	db	cr,lf,lf
	db	'Sends an image of an Altair 1.5Mb floppy disk to a PC via an'
	db	cr,lf
	db	'88-2SIO or 88-SIO serial port, using the XMODEM protocol.',0

mDrive	db	cr,lf,lf,'Insert and specify source drive ('
mDrvMin	db	'x-'
mDrvMax	db	'x) or X to exit: ',0

mPort	db	cr,lf,lf
	db	'Specify the port to use for file transfer',cr,lf
	db	'  1) 88-2SIO port A (which is also the console)',cr,lf
	db	'  2) 88-2SIO port B',cr,lf
	db	'  3) 88-SIO',cr,lf
	db	'Enter port or X to exit: ',0

mStart	db	cr,lf,lf,'Start XMODEM receive operation on the PC now...',0

mDone	db	cr,lf,lf,'Transfer complete!',cr,lf,0

mXmdm	db	cr,lf,lf,'XMODEM communication failure',cr,lf,0

mNoTrk0	db	cr,lf,lf,'Seek to track 0 failed',cr,lf,0

mTrkErr	db	cr,lf,'Read error on track '
errTrk	db	'xxx',0

mExit	db	cr,lf,lf,'Exiting...',cr,lf,0

mCpm	db	cr,lf,lf
	db	'Insert CP/M disk into drive A, then press Return...',0


;****************************************************************************
;
;  Hardware specific console and serial I/O routines. 
;     The following four routines must be written to provide a common
;     interface to the hardware on which this program is running. The
;     port number specified for serIn and serOut matches the port number
;     input from the operator via the port menu.
;
;****************************************************************************

; 88-2SIO Serial Board Equates

s2aCtl	equ	010h		;1st port on 88-2SIO board - control register
s2aDat	equ	011h		;1st port on 88-2SIO board - data register
s2bCtl	equ	012h		;2nd port on 88-2SIO board - control register
s2bDat	equ	013h		;2nd port on 88-2SIO board - data register
s2Rdrf	equ	001h		;read data register full flag
s2Tdre	equ	002h		;transmit data register empty flag
s2Rst	equ	003h		;reset command
s28n1	equ	015h		;8N1 selection
s28n2	equ	011h		;8N2 selection

; 88-SIO Serial board Equates

sioCtl	equ	00h		;control port
sioDat	equ	01h		;data port
sioRdrf	equ	00000001b	;-RX Data register full
sioTdre	equ	10000000b	;-TX Data register empty

; The rcvByte subroutine above times a one second timeout with a code
;    loop that calls the hardware specific serIn routine below. ONESEC
;    must be set based on processor speed and the number of cycles in 
;    the serIn call + 59 cycles for the rcvByte code. 

ONESEC	equ	19231		;rcvByte loop count for 1 second

;----------------------------------------------------------------------------
; s2Init - reset and initialize 88-2SIO ports for 8N1
;----------------------------------------------------------------------------
s2Init	mvi	a,s2Rst	;reset and init 2nd 88-2SIO port
	out	s2bCtl
	mvi	a,s28n1	;transfer port as 8N1
	out	s2bCtl

; if not running under CP/M, reset and init 1st 88-2SIO port

	lda	cpmFlag		;running under CP/M?
	ora	a
	rnz			;yes, 2SIO already initialized
	mvi	a,s2Rst	;reset and init 1st 2SIO port
	out	s2aCtl
	mvi	a,s28n2	;configure console for 8N2 in case Teletype
	out	s2aCtl
	ret	

;----------------------------------------------------------------------------
; conIn - input character from console
;    inputs:
;    outputs: z true if no character present
;	      z false if character returned in a
;    clobbers none
;----------------------------------------------------------------------------
conIn	in	s2aCtl		;see if a new character is present
	ani	s2Rdrf
	rz			;no character, return zero status
	in	s2aDat		;return character and non-zero status
	ret	

;----------------------------------------------------------------------------
; conOut - output character to console
;    inputs: b = character to send
;    clobbers a
;----------------------------------------------------------------------------
conOut	in	s2aCtl		;wait for OK to transmit
	ani	s2Tdre
	jz	conOut
	mov	a,b		;a=character to transmit
	out	s2aDat		;send it
	ret

;----------------------------------------------------------------------------
; Hardware specific I/O
; serIn - input character from port specified in a
;       0 = 88-2SIO port A
;       1 = 88-2SIO port B
;       2 = 88-SIO
;    inputs: a = port to read from
;    outputs: z true if no character present
;	      z false if character returned in a
;    clobbers none
; 88-2SIO Port A: 53 cycles including return when no character present
; 88-2SIO Port B: 43 cycles including return when no character present
; 88-SIO: 57 cycles including return when no character present
;-----------------------------------------------------------------------------
serIn	dcr	a		;(5)3-way test
	jz	s2InB		;(10)a was 1: 88-2SIO port B
	jp	sioIn		;(10)a was 2: 88-SIO
				;    a was 0: 88-2SIO port A
; Input from 88-2SIO port A

s2InA	in	s2aCtl		;(10+1)see if a new character is present
	ani	s2Rdrf		;(7)
	rz			;(10)no character, return zero status
	in	s2aDat		;return character and non-zero status
	ret	
	
; Input from 88-2SIO port B

s2InB	in	s2bCtl		;(10+1)see if a new character is present
	ani	s2Rdrf		;(7)
	rz			;(10)no character, return zero status
	in	s2bDat		;return character and non-zero status
	ret	

;Input from 88-SIO

sioIn	in	sioCtl		;(10+1)see if a new character is present
	cma			;(4)invert Rx Data Ready flag
	ani	sioRdrf		;(7)
	rz			;(10)no character, return zero status
	in	sioDat		;return character and non-zero status
	ret	

;-----------------------------------------------------------------------------
; Hardware specific I/O
; serOut - output character to port specified in a
;       0 = 88-2SIO port A
;       1 = 88-2SIO port B
;       2 = 88-SIO
;    inputs: a = port to transmit through
;	     b = character to send
;    clobbers a
;-----------------------------------------------------------------------------
serOut	dcr	a		;3-way test
	jz	s2OutB		;a was 1: 88-2SIO port B
	jp	sioOut		;a was 2: 88-SIO
				;a was 0: 88-2SIO port A

; Send character through 88-2SIO port A

S2OutA	in	s2aCtl		;wait for OK to transmit
	ani	s2Tdre
	jz	S2OutA
	mov	a,b		;a=character to transmit
	out	s2aDat		;send it
	ret

; Send character through 88-2SIO port B

s2OutB	in	s2bCtl		;wait for OK to transmit
	ani	s2Tdre
	jz	s2OutB
	mov	a,b		;a=character to transmit
	out	s2bDat		;send it
	ret

; Send character through 88-SIO

sioOut	in	sioCtl		;wait for OK to transmit
	ani	sioTdre
	jnz	sioOut		;active-low flag
	mov	a,b		;a=character to transmit
	out	sioDat		;send it
	ret

;****************************************************************************
;
; Altair disk I/O routines
;
;****************************************************************************

; MITS Disk Drive Controller Equates

drvSel	equ	8		;drive select port (out)
drvStat	equ	8		;drive status port (in)
drvCtl	equ	9		;drive control port(out)
drvSec	equ	9		;drive sector position (in)
drvData	equ	10		;drive read/write data
drvTrk	equ	11		;OUT to provide track to FDC+
drvIos	equ	11		;IN for I/O operation status

sCrcErr	equ	01h		;1=checksum error
sTrkErr	equ	02h		;1=track number error
sEosErr	equ	04h		;1=unexpected end of sector
sDone	equ	80h		;1=disk I/O complete
sErrMsk	equ	(NOT sDone) AND 0FFh

enwdMsk	equ	01h		;enter new write data bit mask
headMsk	equ	04h		;mask to get head load bit alone
moveMsk	equ	02h		;mask to get head move bit alone
xfrDone	equ	10h		;sector transfer complete
trk0Msk	equ	40h		;mask to get track zero bit alone

dSelect	equ	80h		;deselects drive when written to drvSel
selMask	equ	08h		;zero when selected, one otherwise

dcStepI	equ	01h		;drive command - step in
dcStepO	equ	02h		;drive command - step out
dcLoad	equ	04h		;drive command - load head
dcUload	equ	08h		;drive command - unload head
dcRead	equ	10h		;drive command - read request
dcHcs	equ	40h		;drive command - low current
dcWrite	equ	80h		;drive command - start write sequence

;---------------------------------------------------------------------------
; dRead - Read a track (one sector per track)
;
; On Entry
;    Drive is selected, sector true just detected
;    HL->track buffer
;
; On Exit
;    Track read to (HL)
;    A=I/O status byte from FDC+
;    Zero true if no error, false otherwise
;    Clobbers B,C,H,L
;---------------------------------------------------------------------------
dRead	lxi	b,TRKLEN/2	;BC=transfer counter
	mvi	a,dcRead	;issue read request
	out	drvCtl

drWait	in	drvStat		;wait for ok to read data
	ora	a
	jm	drWait

	in	drvData		;dummy read to start the transfer

; drFifo - Read data without handshake. Data should be read slower than
;    the physical transfer rate of 16us/byte. This loop averages 17us/byte.

drFifo	in	drvData		;(10) get and store a byte
	mov	m,a		;(7)
	inx	h		;(5)

	in	drvData		;(10) get and store abyte
	mov	m,a		;(7)
	inx	h		;(5)

	dcx	b		;(5) decrement transfer counter
	mov	a,b		;(5)
	ora	c		;(4)
	jnz	drFifo		;(10)

	in	drvIos		;get the I/O status
	ani	sErrMsk		;test the error bits
	ret

;-----------------------------------------------------------------------
; dSeek - Seek Track. The cylinder to step to is 1/2 the track number
;    with even tracks on the bottom and odd tracks on the top. This is
;    true until track 144 is reached (cylinder 72). For tracks 144-148,
;    only the bottom side is written and correspond to cylinders 72-76.
; On Entry:
;    curTrk = current track, FFh means we don't know
;    l = desired track
; On Exit:
;    curTrk = current track
; trashes all registers
;-----------------------------------------------------------------------
dSeek	call	dSelDrv		;make sure drive is selected
	lda	curTrk		;where are we?
	cpi	0ffh
	cz	dRestor		;lost: restore (assumes a returned 0)

	mov	c,a		;C=current track
	mov	a,l		;A=requested track
	sta	curTrk		;save as new current track
	out	drvTrk		;give track number to FDC+
	cmp	c		;requested=current?
	rz			;yes, just exit
	
; Put proper cylinder for the new track in B

	cpi	ENDTOP		;reached topside track limit?
	jc	dsDiv1		;no, go compute cylinder=track/2
	sui	ENDTOP/2	;convert track to cylinder
	mov	b,a		;B=requested cylinder
	jmp	dsDoCur		;go do curTrk
	
dsDiv1	ora	a		;clear carry for rotate
	rar			;A=requested cylinder
	mov	b,a		;B=requested cylinder

; Get proper cylinder for previous track (curTrk)

dsDoCur	mov	a,c		;A=current track
	cpi	ENDTOP		;reached topside track limit?
	jc	dsDiv2		;no, go compute cylinder=track/2
	sui	ENDTOP/2	;convert track to cylinder
	jmp	dSubCyl		;go subtract cylinders

dsDiv2	ora	a		;clear carry for rotate
	rar			;A=current cylinder
	
; Subtract previous cylinder from new cylinder and compute step count

dSubCyl	sub	b		;A=current-requested
	jz	dsSide		;same cylinder, different side

	mvi	b,dcStepO	;B=step out (assume current>requested)
	jnc	dDoSeek		;it is

	mvi	b,dcStepI	;B=step in (current<requested)
	cma			;compute A=-A
	inr	a

dDoSeek	mov	h,a		;C=number of steps
	jmp	dStep		;do the seek

; dsSide- Already on the correct cylinder but different track. This
;    means the side select will change. Delay 200us for the side
;    select to settle

dsSide	mvi	a,2		;delay 2x100us
	jmp	delay		;delay and exit with zero status

;--------------------------------------------------------------
; dRestor - Restore to track 0
; On Exit:
;    a=0
;    curTrk=0
; trashes b,c,h (c not clobbered in this version)
;--------------------------------------------------------------
dRestor	call	dSelDrv		;make sure drive is selected
	xra	a
	sta	curTrk		;set current drive track to zero
	in	drvStat		;test for track 0
	ani	trk0Msk
	rz			;at track 0, exit

; Step in three tracks, then step out to track 0

	mvi	h,3		;h=step in 3 tracks
	mvi	b,dcStepI	;b=step in command
	call	dStep		;do 3 steps in
	rz			;already reached track 0

; Seek back out until track 0 detected

	mvi	h,84	;maximum number of step outs to try
	mvi	b,dcStepO	;step out command
	call	dStep		;step out until track 0
	rz			;track zero reached

; Too many steps, can't find track 0. Display error and start the
;   program over

	call	dUnload		;unload drive head
	lxi	h,mNoTrk0
	call	dispMsg
	lxi	sp,ourStk	;initialize stack pointer
	jmp	getDrv		;start over asking for drive num

;--------------------------------------------------------------
; dStep - Step head (not a required entry). After seek operation
;   is complete, wait an additional 30ms in case another seek
;   operation immediately follows in the opposite direction.
; On Entry:
;   h = number of steps, >0
;   b = step command (dcStepO or dcStepI)
; On Exit:
;   Z set and curTrk=0 if track 0 found
; trashes b,c,h
;--------------------------------------------------------------
dStep	mov	a,b		;a=step command and direction
	out	drvCtl		;issue the step
dStepLp	in	drvStat		;loop until OK to move the head again
	ani	moveMsk
	jnz	dStepLp

; see if we hit track zero while stepping. If so, return with z
;   set and curTrk = 0

	in	drvStat		;test for track 0
	ani	trk0Msk
	jz	dStep0		

; not track zero. Loop until the specified number of steps is done

	dcr	h		;decrement step counter
	jnz	dStep		;loop until count reaches zero
	mvi	a,200		;delay 20ms for possible dir change
	call	delay
	inr	h		;for non-zero status
	ret

;  We stepped to track 0 during this operation. Return with
;     curTrk set to 0 and the Z flag true

dStep0	sta	curTrk		;curTrk = 0
	mvi	a,20		;delay 20ms for possible dir change
	call	delay
	ret			;return with z true

;-----------------------------------------------------------------------------
; delay - delay for A x 100us
;   clobbers B,C
;-----------------------------------------------------------------------------
delay	mvi	b,CPUSPED/(20*10)  ;B=20 cycle loops for 100us

delayLp	mov	b,b		;(5) delay 5 cycles
	dcr	b		;(5)
	jnz	delayLp		;(10)

	dcr	a		;decrement 100us counter
	jnz	delay
	ret

;--------------------------------------------------------------
; dSelDrv - Select drive in drvNum (not a required entry)
;   If the drive is not already selected, deselect the old
;   drive and select the new drive.
; On Entry:
;    curDrv = drive currently selected, FFh means we don't know
;    drvNum = desired drive to be selected
; On Exit:
;    curDrv = current selected Drive
; Clobbers none
;--------------------------------------------------------------
dSelDrv	push	h		;save hl
	lxi	h,curDrv	;hl->currently selected drive
	lda	drvNum		;a=desired drive
	cmp	m		;proper drive already chosen?
	mov	m,a		;curDrv=drvNum
	jz	dVfySel		;yes, verify it's selected

; De-select current drive and select desired drive until the
;   drive is selected

dSelLp	mvi	a,dSelect	;deselect a possibly attached drive
	out	drvSel
	lda	drvNum		;a=drive to select
	out	drvSel		
dVfySel	in	drvStat		;loop until drive is selected
	ani	selMask		;drive selected?
	jnz	dSelLp		;no, try again
	pop	h		;restore hl
	ret

;--------------------------------------------------------------
; dDeslct - Deselect drive in drvNum (not a required entry)
;--------------------------------------------------------------
dDeslct	mvi	a,dSelect	;select code to de-select drive
	out	drvSel		
	ret

;--------------------------------------------------------------
; dLoad, dUnload - Load and unload head (drive-specific entry)
;   The head load is not issued if the head is already
;   settled so we don't re-start the head load one-shot.
; On Entry:
;    Drive is selected
; On Exit:
;    head loaded/unloaded
;--------------------------------------------------------------
dLoad	in	drvStat		;head loaded already?
	ani	headMsk
	rz			;yes, exit
	mvi	a,dcLoad	;issue the load head command
	out	drvCtl
	ret
	
; Head unload

dUnload	mvi	a,dcUload	;issue head unload command
	out	drvCtl
	ret

;---------------------------------------------------------------------------
; dNxtSec - Wait for the index pulse, point HL to trkBuf
;
; On Entry
;    Drive is selected, head loaded
;
; On Exit
;    HL->track buffer
;    Sector true has just occurred
;---------------------------------------------------------------------------
dNxtSec	in	drvSec		;read sector position register
	rar			;wait for sector true (0=true)
	jc	dNxtSec
	
	lhld	trkPtr		;HL->track buffer
	ret
	
;**************************************************************************
; 
;  Data area
;
;**************************************************************************
; disk variables

drvNum	ds	1		;drive number to use
curDrv	ds	1		;drive currently selected
curTrk	ds	1		;current track number drive is on
trkNum	ds	1		;track number to read
trkPtr	ds	2		;pointer into trkBuf at track boundaries
bufEnd	ds	2		;end address + 1 of last track spot in RAM

; xmodem variables

xfrPort	ds	1		;pseudo port for file transfer
xmRetry	ds	1		;xmodem retry counter
blkNum	ds	1		;current xmodem block number
crcFlag	ds	1		;non zero if using CRC instead of checksum
crc16	ds	2		;crc-16 result
sndPtr	ds	2		;pointer for start of XMODEM send

; misc variables

cpmFlag	ds	1		;non-zero if running under CP/M
baseDrv	ds	1		;ascii 1st drive - baseDrv = 0
	ds	64		;stack space
ourStk	equ	$

; track buffer runs from here to the end of memory

	ds	PKTLEN		;space for pre-pended unsent data
trkBuf	equ	$

	end
