Files on disks written under single user BASIC may appear to
be password locked when accessed under Timesharing BASIC. The
following program can be run under single user BASIC to remove
"junk" password bytes that may be in the directory. The disk
will then work properly under both single user and Timesharing
BASIC.


10 CLEAR 500
30 DT=70                ' MOVE TO TRACK 70
40 IF (INP(8) AND 64) <> 0 THEN WAIT 8,2,2: OUT 9,2:GO TO 40
60 IF DT<0 OR DT>76 THEN PRINT "ERROR": STOP
70 FOR K=1 TO DT: WAIT 8,2,2: OUT 9,1: NEXT K
100 FOR SC=0 TO 31      ' GET EACH SECTOR OF TRACK 70
110 A$=DSKI$(SC)        ' READ CURRENT SECTOR
120 FOR SL=0 TO 7       ' GET EACH FILE NAME SLOT (8 SLOT/SECTOR)
130 Y$=STRING$(5,0)
140 MID$(A$,19+(SL*16),5)=Y$
160 NEXT SL             ' GET NEXT SLOT
180 CK=0                ' SET CHECKSUM COUNTER TO ZERO
190 FOR I=6 TO 135      ' ADD UP BYTES 6 THROUGH 135
200 CK=CK+ASC(MID$(A$,I,1))
210 NEXT I
220 FOR J=3 TO 4        ' ADD BYTES 3 AND 4 TO THE SUM OF 6-135
230 CK=CK+ASC(MID$(A$,J,1))
240 NEXT J 
250 CK=CK AND 255       ' MASK OUT HIGH ORDER 8 BITS
260 MID$(A$,5,1)=CHR$(CK)  ' REPLACE BYTE 5 WITH NEW CHECKSUM
270 DSKO$ A$, SC        ' PUT MODIFIED SECTOR BACK ON DISK
280 NEXT SC             ' GET NEXT SECTOR
290 PRINT "DONE"